Art Of Creation - Dynamics AX Blog » SQL

Linked server sql statements

Klaas Deforche — Fri, 23 Jul 2010 16:29:55 +0000

Hi all, hope you are well.

Some time ago, I talked about executing direct sql statements, and now I want to share some sql statements that I used to manage linked server connections.

What follows are 4 sql statements that allow you to add en remove linked servers on a database at runtime.

Some assumptions:
- There is a str variable named “query” that will contain the query
- there is a parm method on the class that return the sql server (“server” or “server\instance”)
- there is a parm method that returns a username
- there is a parm method that returns a password

Check if linked server exist
First check if the linked server doesn’t exist yet, or you will get an error when you try to add one that already exists.

query = strfmt("select top 1 * from sys.servers where name = '%1'", this.parmServer());

Add linked server
When the linked server doesn’t exist, add it.

query = strfmt("EXEC sp_addLinkedServer @server = '%1', @srvproduct=N'SQL Server'", this.parmServer());

Add linked server login
Optionally, you can add a login that will be used to connect to the linked server.

query = strfmt("sp_addlinkedsrvlogin @rmtsrvname = '%1' ,@useself = FALSE, @locallogin = NULL, @rmtuser = '%2', @rmtpassword = '%3'",
this.parmServer(),
this.parmUsername(),
this.parmPassword());

Remove linked server
Optionally, you can remove the linked server.

query = strfmt("EXEC sp_dropserver '%1', 'droplogins'", this.parmServer());

Executing direct SQL statements

Klaas Deforche — Mon, 21 Jun 2010 16:35:22 +0000

Hi everyone,

Today I want to talk about executing SQL statements in X++ on both the AX database and external databases. This is something probably every AX developer will have to do at some point.

You’ll want to do this for many reasons; to execute stored procedures, to improve performance, to get data from an external database, and so on.

I will provide samples for two classes:
- Connection (Execute SQL statement on current AX database)
- ODBCConnection (Execute SQL statement on external database)

I will not cover the ADO connection (CCADOConnection class), because it doesn’t work when you run it on server (or in batch), and I don’t like that. If you do, try to convince me ;-).

Executing direct SQL on the current AX database

When you execute a SQL statement, there are two options:
- either you did a select and you expect a result to be returned
- or you did insert/update/delete and you don’t expect a result.

The first sample is for a SQL statement that returns a result:

public static server void main(Args _args)
{
Connection connection;
Statement statement;
str query;
Resultset resultSet;
;

// create connection object
connection = new Connection();

// create statement
statement = connection.createStatement();

// Set the SQL statement
query = 'select name from CustTable';

// assert SQL statement execute permission
new SqlStatementExecutePermission(query).assert();

// when the query returns result,
// loop all results for processing
//BP Deviation documented
resultSet = statement.executeQuery(query);

while(resultSet.next())
{
// do something with the result
info(resultSet.getString(1));
}

// limit the scope of the assert call
CodeAccessPermission::revertAssert();
}

Note: this is a main method, put it in a class. Also note that it has to run on server.

Now if you do an update/delete/insert, you will want to do something like this:

public static server void main(Args _args)
{
Connection connection;
Statement statement;
str query;
;

// create connection object
connection = new Connection();

// create statement
statement = connection.createStatement();

// Set the SQL statement
query = "insert into CustTable (AccountNum, Name, RecId) values ('demo', 'demo', 2)";

// assert SQL statement execute permission
new SqlStatementExecutePermission(query).assert();

//BP Deviation documented
statement.executeUpdate(query);

// limit the scope of the assert call
CodeAccessPermission::revertAssert();
}

You can find more info about the executeQuery() and executeUpdate() methods on msdn:
Statement Class

Executing direct SQL on an external database using ODBC

Again, we have to differentiate between queries that return a result and those that don’t.

The following code sample retrieves records from an external database and processes the result:

public static server void main(Args _args)
{
Statement statement;
str query;
Resultset resultSet;
LoginProperty loginProperty;
OdbcConnection odbcConnection;
;

loginProperty = new LoginProperty();
loginProperty.setDSN('YOURDSN');

odbcConnection = new OdbcConnection(loginProperty);

// Create new Statement instance
statement =odbcConnection.CreateStatement();

// Set the SQL statement
query = 'select name from CustTable';

// assert SQL statement execute permission
new SqlStatementExecutePermission(query).assert();

// when the query returns result,
// loop all results for processing by handler
//BP Deviation documented
resultSet = statement.executeQuery(query);

while(resultSet.next())
{
// do something with the result
info(resultSet.getString(1));
}

// limit the scope of the assert call
CodeAccessPermission::revertAssert();
}

As you can see, the code is pretty similar. The main difference is that we are using ODBC classes, including the LoginProperty class.

In this example, I use a DSN (Data Source Name) that I configured on the AOS server. The DSN contains a reference to the server and database you want to connect to, and also what user credentials should be used to connect to the database. This is a lot safer than storing them in AX.
If you don’t know how to create a DSN, there are plenty of tutorials on the web.

To update/delete/update, the code is more or less the same:

public static server void main(Args _args)
{
Statement statement;
str query;
LoginProperty loginProperty;
OdbcConnection odbcConnection;
;

loginProperty = new LoginProperty();
loginProperty.setDSN('YOURDSN');

odbcConnection = new OdbcConnection(loginProperty);

// Create new Statement instance
statement =odbcConnection.CreateStatement();

// Set the SQL statement
query = "insert into CustTable (AccountNum, Name, RecId) values ('demo', 'demo', 2)";

// assert SQL statement execute permission
new SqlStatementExecutePermission(query).assert();

// when the query returns result,
// loop all results for processing by handler
//BP Deviation documented
statement.executeUpdate(query);

// limit the scope of the assert call
CodeAccessPermission::revertAssert();
}

If you feel that something is missing in these examples, just ask.

Split and Add ranges on datasource

Klaas Deforche — Fri, 09 Apr 2010 08:43:10 +0000

When creating a query and adding ranges, you might notice that there is a limit on how the range string can be. This limit is defined by the extended data type Range that you can find in the AOT. You can try extending the size to a bigger stringsize, but you can’t go too high before you run into limits that the sql database will have (I think this value is around 1700 characters).

What you can do is add multiple smaller ranges on the same field in stead of one long range.

I’ve written a method that splits a long range and adds it to you queryBuildDataSource:

private static void splitAndAddRange(QueryBuildDataSource _qbds,
fieldId _fieldId,
str _sRange)
{
#AOT
// used to split and build ranges
int splitPos; // max position for splitting
int cPos; // position of ','
str fRange; // first part of the range
str lRange; // last part of the range
QueryBuildRange qbr; // the extra qbr if needed
;

// define max lenght
// note: make this function none static and get the stringsize property only once while initialising your class
// to speed up performance
splitPos = treenode::findNode(#ExtendedDataTypesPath + #AOTRootPath + 'Range').AOTgetProperty('StringSize');
// define range string

// init cPos
cPos = -1;
// if range is too long -> split (3 should be 1500)
if(strlen(_sRange) > splitPos)
{
// while no comma found
while(cPos == -1 && splitPos > 0)
{
// if char at current position is ',', split position found
if(substr(_sRange, splitPos, 1) == ',')
cPos = splitPos;
// else try prev char
else
splitPos--;
}

// get the first part of the range
fRange = substr(_sRange, 0, splitPos - 1);
// make new range and add it
qbr = _qbds.addRange(_fieldId);
qbr.value(fRange);

// get the remaining part of the range
lRange = substr(_sRange, splitpos, strlen(_sRange));

// split the rest of the range
if(strlen(lRange) > 0)
{
KLFSplitAndAddRangeTest::splitAndAddRange(_qbds, _fieldId, lRange);
}
}
else
{
// range is not too long, don't split, just add
qbr = _qbds.addRange(_fieldId);
qbr.value(_sRange);
}
}

When you put this method in a class along with the following one, you can test the method.

static void main(Args _args)
{

Query query;
QueryBuildDataSource qbds;
str accountNumRange;

// used for info-ing
int rangeLength;
int rangeLengthAOT;
#AOT
;

accountNumRange += 'A0000000001,A0000000002,A0000000003,A0000000004,A0000000005,A0000000006,A0000000007,A0000000008';
accountNumRange += '0000000009,A0000000010,A0000000011,A0000000012,A0000000013,A0000000014,A0000000015,A0000000016';
accountNumRange += '0000000017,A0000000018,A0000000019,A0000000020,A0000000021,A0000000022,A0000000023,A0000000024';
accountNumRange += '0000000025,A0000000026,A0000000027,A0000000028,A0000000029,A0000000030,A0000000031,A0000000032';
accountNumRange += '0000000033,A0000000034,A0000000035,A0000000036,A0000000037,A0000000038,A0000000039,A0000000040';
accountNumRange += '0000000041,A0000000042,A0000000043,A0000000044,A0000000045,A0000000046,A0000000047,A0000000048';
accountNumRange += '0000000049,A0000000050,A0000000051,A0000000052,A0000000053,A0000000054,A0000000055,A0000000056';
accountNumRange += '0000000057,A0000000058,A0000000059,A0000000060,A0000000061,A0000000062,A0000000063,A0000000064';
accountNumRange += '0000000065,A0000000066,A0000000067,A0000000068,A0000000069,A0000000070,A0000000071,A0000000072';
accountNumRange += '0000000073,A0000000074,A0000000075,A0000000076,A0000000077,A0000000078,A0000000079,A0000000080';
accountNumRange += '0000000081,A0000000082,A0000000083,A0000000084,A0000000085,A0000000086,A0000000087,A0000000088';
accountNumRange += '0000000089,A0000000090,A0000000091,A0000000092,A0000000093,A0000000094,A0000000095,A0000000096';
accountNumRange += '0000000097,A0000000098,A0000000099,A0000000100';

query = new Query();

rangeLength = strlen(accountNumRange);
rangeLengthAOT = treenode::findNode(#ExtendedDataTypesPath + #AOTRootPath + 'Range').AOTgetProperty('StringSize');

info(strfmt('Range length: %1',rangeLength));
info(strfmt('range length AOT: %1', rangeLengthAOT));
info(strfmt('There should be %1 ranges', roundup(rangeLength / rangeLengthAOT, 1)));

qbds = Query.addDataSource(tablenum(CustTable));

KLFSplitAndAddRangeTest::splitAndAddRange(qbds, fieldnum(CustTable, AccountNum), accountNumRange);

info(strfmt('Range count: %1',qbds.rangeCount()));
}

The output is:

Range length: 1175
range length AOT: 250
There should be 5,00 ranges
Range count: 5

Using a tool I have I can also print out the query for a closer look:

You can clearly see that the 5 ranges have been added.

Rename an AX company on SQL

Klaas Deforche — Wed, 24 Feb 2010 21:57:25 +0000

A while ago, I talked about deleting an AX company on SQL, but of course, you can also use the sp_MSforeachtable stored procedure to rename a company (= change the DataAreaId of a company).

In the next example, I rename CEE to CEA:

exec sp_MSforeachtable 'update ? set DataAreaID = "CEA" where ?.DataAreaID = "CEE"'

UPDATE DataArea SET ID = 'CEA' WHERE DataArea.ID = 'CEE'
UPDATE CompanyDomainList SET CompanyID = 'CEA' WHERE CompanyID = 'CEE'

Delete an AX company on SQL

Klaas Deforche — Wed, 03 Feb 2010 20:03:53 +0000

This week, we were shrinking a database of a development environment by deleting some companies.
Here a nice little SQL statement that uses the sp_MSforeachtable stored procedure to delete all records of a specific company (CEU in this case) from all tables.

exec sp_MSforeachtable 'delete from ? where ?.DataAreaID = "CEU"'

Certainly fast(er than AX) and gets the job done.
Use at your own risk ;-)

Update:
You’ll want do do some cleaning up to:
delete the company id from the DataArea table and from the CompanyDomainList table

DELETE FROM DataArea WHERE DataArea.ID = 'CEU'
DELETE FROM CompanyDomainList WHERE CompanyDomainList.CompanyID = 'CEU'

Update 2:
When you want to delete all companies execpt a few (like DAT), just use this:

exec sp_MSforeachtable 'delete from ? where ?.DataAreaID <> "DAT" AND ?.DataAreaID <> "DEMO"'
DELETE FROM DataArea WHERE DataArea.ID <> 'DAT' AND DataArea.ID <> 'DEMO'
DELETE FROM CompanyDomainList WHERE CompanyDomainList.CompanyID <> 'DAT' AND CompanyDomainList.CompanyID <> 'DEMO'

This will delete all companies except DAT en DEMO.