Art Of Creation - Dynamics AX Blog » Job

Data migration: Importing the InventItemGroupForm Table

Klaas Deforche — Tue, 08 Nov 2011 10:23:53 +0000

Hi everyone :-).

I am tasked with doing data migration for a project that is about to go live. One of the things that have to be converted are item groups (InventItemGroup) and their linked dimensions (InventItemGroupForm).

Importing the InventItemGroup table is easy, but InventItemGroupForm is a little bit trickier.
There is a job below that shows how to fill in the LedgerDimension field on the InventItemGroupForm table. I’m not saying I completely understand the new dimension framework, but this method worked for me, and I hope it helps you when you have to do the same thing.

You will notice that you won’t be able to import the InventItemGroupForm table with the excel add-on. You’ll have to use a custom job (or make you own import framework like I did).

This white paper can help too: Implementing the Account and Financial Dimensions Framework (White paper)

static void klforDimensionTest(Args _args)
{
/* input */

// the InventItemGroup record we want to set accounts for
InventItemGroup inventItemGroup = InventItemGroup::find("Car Audio");
// the main account we want to link to our InventItemGroup
MainAccountNum mainAccountNum = "0107";
// The account type we are setting
InventAccountType inventAccountType = InventAccountType::InventIssue;
// the dimension group of the account type
ItemGroupLedgerDimensionGroup itemGroupLedgerDimensionGroup = ItemGroupLedgerDimensionGroup::Inventory;

/* declarations */
Ledger ledger;
MainAccount mainAccount;
DimensionAttributeValueCombination dimensionAttributeValueCombination;
DimensionAttributeValue dimAttributeValue;
DimensionAttribute dimAttribute;
DimensionStorage dimStorage;
RecId hierarchyRecId;

DimensionStorageSegment dimensionStorageSegment;
InventItemGroupForm inventItemGroupForm;
;

if(inventItemGroup.RecId == 0)
{
throw error("InventItemGroup not found");
}

// check if inventItemGroupForm record exists
select firstOnly forUpdate inventItemGroupForm
where inventItemGroupForm.ItemGroupId == inventItemGroup.ItemGroupId
&& inventItemGroupForm.InventAccountType == inventAccountType
&& inventItemGroupForm.LedgerDimensionGroup == itemGroupLedgerDimensionGroup;

if(!inventItemGroupForm)
{
// record does not exists, initialize it
inventItemGroupForm.clear();
inventItemGroupForm.initValue();
inventItemGroupForm.ItemGroupId = inventItemGroup.ItemGroupId;
inventItemGroupForm.InventAccountType = inventAccountType;
inventItemGroupForm.LedgerDimensionGroup = itemGroupLedgerDimensionGroup;
}

// get the ledger record for the current company
ledger = Ledger::findByLegalEntity(CompanyInfo::current());

// lookup main account record
mainAccount = MainAccount::findByMainAccountId(mainAccountNum, false, ledger.ChartOfAccounts);

if (mainAccount.RecId == 0)
{
throw error("MainAccount not found");
}

// check if DAVC exists
select firstOnly dimensionAttributeValueCombination
where dimensionAttributeValueCombination.MainAccount == mainAccount.RecId
&& dimensionAttributeValueCombination.AccountStructure == 0
&& dimensionAttributeValueCombination.LedgerDimensionType == LedgerDimensionType::DefaultAccount;

// when the DAVC does not exist, create it
if(dimensionAttributeValueCombination.RecId == 0)
{
// Cache the dimension attribute that represents the Main account
select firstonly * from dimAttribute where
dimAttribute.RecId == DimensionAttribute::getMainAccountDimensionAttribute();

// Lookup the DAV backing the main account instance
dimAttributeValue = DimensionAttributeValue::findByDimensionAttributeAndEntityInst(dimAttribute.RecId, mainAccount.RecId, false, true);

// lookup the hierarchy for the default acount
hierarchyRecId = DimensionHierarchy::getHierarchyIdByHierarchyType(DimensionHierarchyType::DefaultAccount);

// create new storage
dimStorage = DimensionStorage::construct();
// add the default account structure hierarchy
dimStorage.addAccountStructure(hierarchyRecId);

// create storage segment for the value
dimensionStorageSegment = DimensionStorageSegment::construct(mainAccountNum, dimAttributeValue.RecId, dimAttributeValue.HashKey);
// add the segment to the storage
dimStorage.setSegment(1, dimensionStorageSegment);

// save storage as default account and get the record
dimensionAttributeValueCombination = DimensionAttributeValueCombination::find(dimStorage.saveAsDefaultAccount());
}

// set the ledgerdimension reference field
inventItemGroupForm.LedgerDimension = dimensionAttributeValueCombination.RecId;
// call modifiedfield voor ledgerdimension field to sync inventPosting
inventItemGroupForm.modifiedField(fieldNum(InventItemGroupForm, LedgerDimension));

ttsBegin;

if(inventItemGroupForm.recid == 0)
{
// insert if this is a new record
inventItemGroupForm.insert();
}
else
{
// update existing record
inventItemGroupForm.update();
}

ttsCommit;

info("Done");
}

Comments with ideas / insights / improvements are welcome as always.

Trivial: by in group by is optional

Klaas Deforche — Wed, 04 Aug 2010 16:11:45 +0000

Here is something I did not know: apparently, the ‘by’ in ‘group by’ is optional.

The following job compiles just fine, and outputs the correct result:

static void KlForGroupBy(Args _args)
{
InventTable inventTable;
;

while select inventTable
group by ItemGroupId
{
info(inventTable.ItemGroupId);
}

info('------');

while select inventTable
group ItemGroupId // without by
{
info(inventTable.ItemGroupId);
}
}

It looks funny though :-).

Split big text files in smaller ones in X++

Klaas Deforche — Wed, 21 Apr 2010 16:16:12 +0000

Below is a job I found useful many times, so don’t want to loose it.
Nothing special, but maybe you’ll find it useful too.

It splits an input text file into smaller files.
As there is one comment line for every line of code (almost), I’m sure you’ll figure it out :-).

static void KlForSplitFile(Args _args)
{
#File
AsciiIO inFile, outFile;
container rec;
int cnt = 0, fileNum = 0;
FileName outFileName;
FileIOPermission filePermissionOrig, outFilePermission;
Set permissionSet = new set(types::Class);

// settings begin
// input file
str _inFileName = @"C:\temp\testsplit\testsplit.csv";
// max number of lines
int _maxrec = 20000;
//settings end
;

//
// first loop to create the permission set
//

// assert permission for read
new FileIOPermission(_inFileName, #io_read).assert();

// create new asciiIo for the file we are reading in
inFile = new AsciiIo(_inFileName,#io_read);

// read file to check how many files will be created
while(inFile.read())
{
if(cnt == _maxrec || cnt == 0)
{
// 1 more file
filenum++;
// create filename
outFileName = strfmt('%1_%2.csv',
substr(_inFileName,1,strlen(_inFileName) - 4), fileNum);
// create permission
outFilePermission = new FileIOPermission(outFileName,#io_write);
// add permission to set
permissionset.add(outFilePermission);
// reset line counter
cnt = 0;
}
// 1 more line
cnt++;
}

// also add fileIn permission to set
filePermissionOrig = new FileIOPermission(_inFileName, #io_read);
permissionset.add(filePermissionOrig);
// revert permission assertion
CodeAccessPermission::revertAssert();

// assert permissions for set
CodeAccessPermission::assertMultiple(permissionset);

//
// loop file again and split
//

// reset counters
fileNum = 0;
cnt = 0;

// create new asciiIo for the file we are reading in
inFile = new AsciiIo(_inFileName,#io_read);

// read file to check how many files will be created
// read ahead
rec = inFile.read();
while(rec)
{
if(cnt == _maxrec || cnt == 0)
{
// 1 more file
filenum++;
// create filename
outFileName = strfmt('%1_%2.csv',
substr(_inFileName,1,strlen(_inFileName) - 4), fileNum);
outFile = new AsciiIO(outFileName,#io_write);
// reset line counter
cnt = 0;
}
// 1 more line
cnt++;
// write to split file
outFile.writeExp(rec);
// read next line
rec = inFile.read();
}

// revert permission assertion
CodeAccessPermission::revertAssert();

info('done');
}

AIF: The class method for the specified action %1 could not be found

Klaas Deforche — Wed, 14 Apr 2010 16:13:46 +0000

When you get this error:

The class method for the specified action %1 could not be found

It probably means you have regenerated you classes using the AIF document wizard, or that you have imported the AIF classes without id’s.

You can use this job to fix the class id’s in the AIFAction table:

static void KlForFixAIFActions(Args _args)
{
AIFAction aIFAction;
ClassId classId;

// inner method:
// spit string at delimeter, keep left substring
str lSplit( str _s, str _delimeter )
{
str s = "";
int pos;
int len = strlen( _s );

pos = strfind( _s, _delimeter, 0, len );
s = strdel( _s,pos,len-pos+1);

return s;
}
;

// fix all actions
while select aIFAction
{
// get 'real' classid
classId = classname2id(lSplit(aIFAction.ActionId, '.'));

// check if classid and classname match
if(aIFAction.ClassId != classId)
{
if(classId == 0)
{
// class does not exist
warning(strfmt("Class %1 does not exist", lSplit(aIFAction.ActionId, '.')));
}
else
{
// doesn't match
// update classid
ttsbegin;
aIFAction.selectForUpdate(true);
aIFAction.ClassId = classId;
aIFAction.update();

info(strfmt('Action %1 updated', aIFAction.ActionId));
ttscommit;
}
}
}

info('done');
}

Remove duplicate key entry from a table

Klaas Deforche — Mon, 12 Apr 2010 16:12:08 +0000

Sometimes, you can’t synchronize a table because is contains duplicate records. This can occur when you change field lengths on a extended data type for example.

I’ve seen people write huge SQL statements, and even jobs that create these SQL statements to remove these duplicates from a table, but there’s actually a easy way to do this in AX.

Say you have a table KLFTestDuplicates that contains duplicates, then simple run the following job to remove them.

static void KLFRemoveDuplicates(Args _args)
{
Set fieldSet = new set(Types::Integer);

DictIndex dictIndex = new DictIndex(
tablenum(KLFTestDuplicates),
indexnum(KLFTestDuplicates, AUniqueIdx));
int i;
;

if(dictIndex.numberOfFields())
{
for(i=1;i<=dictIndex.numberOfFields();i++)
{
fieldSet.add(dictIndex.field(i));
}

ReleaseUpdateDB::indexAllowDup(dictIndex);

ReleaseUpdateDB::deleteDuplicatesUsingIds(tablenum(KLFTestDuplicates), 0, fieldSet);

ReleaseUpdateDB::indexAllowNoDup(dictIndex);
}

info("done");
}

Remember: this is useful when developing and testing, but it will remove data from you database, so use it with caution.

Run AIF inbound and outbound manually

Klaas Deforche — Wed, 17 Feb 2010 17:51:53 +0000

To have AIF import and export message, you have to have 4 batch tasks running (all about it here on TechNet). However, when developing, it is inefficient (and also tad tedious) to wait for those batches.

Here are two jobs to run inbound and outbound messages manually, so you don’t have to wait for the batches to pick them up.

Inbound:

static void KlForrunAIFInbound(Args _args)
{
;
// read the messages
new AifGateWayReceiveService().run();

// process the messages in queue
new AifInboundProcessingService().run();

info("done");
}

Outbound:

static void KlForrunAIFOutbound(Args _args)
{
;
// process messages in queue
new AifOutboundProcessingService().run();

// send messages
new AifGateWaySendService().run();

info("done");
}

Ofcourse, you can put this code in classes, or combine them so they are executed together. Because inbound messages can trigger outbound messages, it’s better to process the inbound messages before the outbound messages.

Axapta 3 menu in AX 2009

Klaas Deforche — Thu, 28 Jan 2010 17:58:32 +0000

Are you one of those people who always minimize the content pane in AX 2009?
Are you one of those people who don’t know what the breadcrumb on top of the AX screen is for?
Do you already execute a job to disable the content pane on startup?

Then you might feel totally nostalgic when you see the Axapta 3 menu appearing after you run the following job in AX 2009.

static void Axapta30Nostalgia(Args _args)
{
Menu menu;
#admin
;

menu = new Menu(#MainMenu);
menu.AOTrun();
}

Run multiple jobs

Klaas Deforche — Thu, 05 Nov 2009 17:34:29 +0000

I’ve noticed some people are visiting this blog looking for code that runs multiple jobs, so here’s a job that does just that.

static void KlFor_runMultipleJobsContainer(Args _args)
{
#AOT // macro for treenode paths
Container jobCont; // container for jobs
int i; // counter for loop
;

// add jobs to the container
jobCont = conins(jobCont, conlen(jobCont) + 1, "klforjob2");
jobCont = conins(jobCont, conlen(jobCont) + 1, "klforjob3");
jobCont = conins(jobCont, conlen(jobCont) + 1, "klforjob2"); // run klforjob2 again

// loop all elements of the container
for(i = 1; i <= conlen(jobCont); i++)
{
// check if the job exists to avoid errors
if(TreeNode::findNode(strfmt(#JobPath, conpeek(jobCont, i))))
{
// run job
TreeNode::findNode(strfmt(#JobPath, conpeek(jobCont, i))).AOTrun();
}
}
}

Easy enough :).