Art Of Creation - Dynamics AX Blog » Data Types

Str2int and IsInteger

Klaas Deforche — Thu, 04 Feb 2010 11:16:50 +0000

Here’s a little ‘be-aware’ I’d like to share.

The function str2int() that converts a string to an integer will return ’0′ if the input string is not an integer, so it is necessary to check if the string is an integer before casting it.

The function that does this is not IsNumeric() like in SQL or VB, but IsInteger().
Alternatively, you can also use str2IntOk(). Both are found in the global class.

I’ve seen people searching for this method (including me), so I just thought I’d share.

Here’s some sample code:

static void klforStr2intAndIsIntegerTest(Args _args)
{
str input_notint = "abc123";
str input_int = "123";

int ret;
;

// be aware, str2int will convert 'non integers' to '0'
// without warning
info(strfmt("%1", str2int(input_notint)));
info(strfmt("%1", str2int(input_int)));

// you can check if a string is an integer with
// the isInteger() function from the global class
// or you the str2IntOk() function
info(strfmt("%1", isInteger(input_notint)));
info(strfmt("%1", isInteger(input_int)));

// check if integer
if(isInteger(input_notint))
{
// cast to integer
ret = str2int(input_notint);
}
else
{
throw error(strfmt("'%1' is not an integer", input_notint));
}
}

Remove leading zeros

Klaas Deforche — Mon, 03 Aug 2009 08:49:55 +0000

Sometimes, you’ll want to add leading zeros, but other times, you’ll have to remove leading zeros from a string.
Here the code that does just that:

static void RemoveLeadingZeros(Args _args)
{
str text = "0000A1337";
;

while(substr(text, 1, 1) == "0")
{
text = substr(text, 2, strlen(text) - 1);
}
info(text);
}

The above example will work for any alphanumeric string.

When you’re sure you’re dealing with numeric strings, you can use this example:

static void RemoveLeadingZeros2(Args _args)
{
str text = "00001337";
;

if(strrem(text, "0123456789") == "")
info(int2str(str2int(text)));
else
error("text is not numeric");
}

You should build in a check because the str2int() function doesn’t throw an error when the input isn’t numeric.

An example I found online also removes leading zeros from a string, but it fails if the first character after the zeros isn’t numeric:

static void RemoveLeadingZeros3(Args _args)
{
str text = "0000A1337"; // doesnt work
// str text = "00001A337"; // works
;

info(strdel(text, 1, strfind(text, "123456789", 1, strlen(text)) - 1));
}

Conclusion:
The first example works best, but you should still be careful when converting the resulting string to other types, as you could get unexpected results.

Wrong argument types in variable assignment – Part 2

Klaas Deforche — Tue, 07 Apr 2009 20:04:00 +0000

In the article Wrong argument types in variable assignment, I wrote about how you can solve this error by using compile forward, but doing that won’t always fix the problem, e.g. when using AnyType.

Anytype is great. It’s a primitive data type can use as a placeholder for any other data type, and comes in handy on many occasions. But don’t use it as a silver bullet, it might backfire.

Consider the next example.

static void AnyType_Test_1(Args _args)
{
utcDateTime dateTime;
AnyType value;
;

value = datetimeutil::utcNow();
dateTime = value;

info(strFmt("%1", dateTime));
}

We are assigning the current date and time to the AnyType variable, than back to a utcDateTime, and sending it to te screen. This neatly produces following output:

7/04/2009 19:27:15

Now consider the following example.

static void AnyType_Test_2(Args _args)
{
utcDateTime dateTime;
AnyType value;
;

value = "Here comes today's date";

value = datetimeutil::utcNow();
dateTime = value;

info(strFmt("%1", dateTime));
}

This produces the following output:

Yes, that’s a blank line. Weird, isn’t it, or is it? MSDN has the answer:

The anytype data types can be automatically converted to dates, enums, integers, reals, strings, guids, int64s, extended data types (records), classes, and containers by assigning a value to the type. [...] However, after you have converted the anytype data type, you cannot then change it to another data type.

In the second example it failed to convert the utcDateTime because we assigned a string to the AnyType variable. This is fault very subtle, because no error or warning is shown when compiling such code, and can easily be overlooked.

Not only can (incorrect) use of AnyType cause faulty output, it can also trigger stack traces.
The following example is inspired by Greg.

static void AnyType_Test_3(Args _args)
{
AnyType value;
;

value = NoYes::Yes;
value = datetimeutil::utcNow();
}

This will show the following error message and stack trace:

Error executing code: Wrong argument types in variable assignment.

It gets even nastier in the next example:

static void AnyType_Test_4(Args _args)
{
utcDateTime dt;
AnyType value = "string";
;

value = 3;
dt = value;
}

This will show you a message box saying:

Internal error number 25 in script.

Note: if you are looking to solve the error above (you can encounter it when trying to send an email from code), you can find the links to the hotfixes for ax 2009 here.

And also the error and stack trace we saw before:

Error executing code: Wrong argument types in variable assignment.

Conclusion: Use AnyType with caution, preferably as argument or return type, and remember that the type can not be change once it has been assigned a value.