Art Of Creation - Dynamics AX Blog

Decisions Spring 2012 – AX Day June 18

Klaas Deforche — Wed, 02 May 2012 18:33:26 +0000

Hi AX-enthusiasts!

Decisions Spring 2012 is a (free online) virtual conference about Dynamics products.
If you didn’t attend the conference in the past, be sure to check it out now because it is a great opportunity meet other AX professionals and expand your knowledge about AX.

The AX Day is on the 18th of June, you can register here.

See you there.

Back online after site maintenance

Klaas Deforche — Wed, 02 May 2012 08:21:48 +0000

Hi all!

You might have noticed that this site was offline for a few hours,
that’s because it has been moved to an upgraded server.

Everything is up and running again, I hope this didn’t cause any inconveniences for you.
Thanks to SiteHosting for helping out.

Adding runtime tasks to a business operation framework service

Klaas Deforche — Mon, 27 Feb 2012 12:34:12 +0000

Hi all!

When I was at the technical conference in Nice last year, I attended the session about performance (BRK224), and during a demo, something interesting was shown: how to add one BOF service as a runtime task to another BOF service in batch.
You can watch the session recording here, the code is shown about 44 minutes, 50 seconds in.

Background: Runtime tasks in Dynamics AX 2009

If you are unfamiliar with runtime tasks and how to use them, read my post about batch multithreading for an explanation. The basic principle stays the same, but in the example below, we will be using the Business Operation Framework (aka BOF, aka SysOperation) instead of RunBaseBatch.

Runtime tasks in Dynamics AX 2012 using BOF

The first thing you’ll need to do, is create 2 BOF services, one that will create the runtime tasks, and one that will represent the runtime task. If you don’t know how to do that, read this post: SysOperation Introduction. You can download the xpo file for the following example below.

KlForSubTaskService: the runtime task

This service will be our runtime task. It’s a regular BOF service, nothing special about it. In my example, the service operation contains some testing code so we can see if our service is working:

class KlForSubTaskService
{
}

[SysEntryPointAttribute]
public void runSubTask(KlForSubTaskDataContract _klForSubTaskDataContract)
{
info(strFmt("%1", _klForSubTaskDataContract.parmTheInt()));
}

The data contract for this service has one member:

[DataContractAttribute]
class KlForSubTaskDataContract
{
Integer theInt;
}

[DataMemberAttribute]
public Integer parmTheInt(Integer _theInt = theInt)
{
theInt = _theInt;

return theInt;
}

KlForBatchJobService: Batch header service

This is the service that will create the runtime tasks. Starting for a regular BOF service, make sure that the service class extends SysOperationServiceBase. This enables us to call the isExecutingInBatch() method later on.

class KlForBatchJobService extends SysOperationServiceBase
{
}

The service operation that creates the runtime tasks looks like this:

[SysEntryPointAttribute]
public void createTasks()
{
BatchHeader batchHeader;
SysOperationServiceController controller;
KlForSubTaskDataContract dataContract;

int i;
;

// for demo purposes, loop 10 times to add 10 runtime tasks
for(i=1;i<=5;i++)
{
if(this.isExecutingInBatch() && !batchHeader)
{
// if no batchheader has been set yet, get it
batchHeader = this.getCurrentBatchHeader();
}

// create new controller for the runtime task
controller = new SysOperationServiceController(classStr(KlForSubTaskService), methodStr(KlForSubTaskService, runSubTask));

// get the data contract
dataContract = controller.getDataContractObject('_klForSubTaskDataContract');
// initialize variables for the data contract
dataContract.parmTheInt(i);

if(this.isExecutingInBatch())
{
// code is running in batch, so add a runtime task
batchHeader.addRuntimeTask(controller, this.getCurrentBatchTask().RecId);
}
else
{
// not in batch

// by default, the tasks will execute in reliable asynchronous mode,
// but you could override it so it executes synchronous
//controller.parmExecutionMode(SysOperationExecutionMode::Synchronous);

// not in batch, just run it
controller.run();
}
}

if(batchHeader)
{
// save the batchheader if it has been created
batchHeader.save();
}

}

For this demo, I created a loop that creates 5 runtime tasks.
When you execute this in batch, you can check the batch task history for the batch to see the tasks that have been created.

You can click the Parameters button to verify if the correct values were used to execute the task.

You can download the XPO here.

Links
Another example can be found on Kenny Saelen’s blog: Business Operation Framework and multi-threading

Microsoft Dynamics Salary Survey 2012

Klaas Deforche — Tue, 17 Jan 2012 19:20:37 +0000

Hi all!

Wondering if you’re getting the right salary?
Nigel Frank is organizing its yearly salary survey for Dynamics professionals.

You’ll get a copy of the results for free if you take part in the survey, and you can also win some prizes.

Just click the banner to take part in the survey.

AX Technical Conference 2011: Session Recordings (Now available)

Klaas Deforche — Tue, 17 Jan 2012 09:31:20 +0000

The session recordings and slides from the Technical Conference in Nice 2011 are available here:
https://mbs.microsoft.com/partnersource/newsevents/news/MSDAXTechnicalConf2011Recordings

AX Technical Conference 2011: Session Recordings

Klaas Deforche — Tue, 20 Dec 2011 13:05:42 +0000

Some of you asked if the session recordings from the Technical Conference in Nice were available online, and I’m glad to inform you that they will be available on PartnerSource starting January 4th, 2012.

Just click this link in early January to view the recordings: ~~https://mbs.microsoft.com/partnersource/training/news/MSDYAX_TechConferenceFall.htm~~ https://mbs.microsoft.com/partnersource/newsevents/news/MSDAXTechnicalConf2011Recordings.

Some of the sessions were really interesting, so be sure to check it out!

Update 2012/01/09: The recordings are not online yet. Will keep you updated.
Update 2012/01/17: Available now!

AX Technical Conference 2011 Day 1: Information Source

Klaas Deforche — Mon, 14 Nov 2011 21:16:58 +0000

Hi everyone, and greetings from the Microsoft Dynamics AX Technical Conference 2011 in Nice.

Among other sessions, I saw Arijit Basu’s session about Implementing AX Technical Solution Architecture, and found it pretty inspiring. He demonstrated a lot of tools and methods that will come in very handy and I’m sure I’ll talk about more on this blog in the future. Tools like the Application Analysis Tool in particular look very promising.

Some of these tools are available through the website that Sri Srinivasan announced: InformationSource (beta).
You can download these in the “Services” section. There is also an extensive library of Q&A’s, and a lot of documentation (Word and Powerpoint documents, video’s,…) that dive deep into what they call Core Concepts of AX.

You will need to log in with your PartnerSource or CustomerSource account.
Be sure to check it out, it’s awesome (really!).

Also, for those who haven’t seen this yet, a nice screenshot of the POS (Point of Sales) of AX For Retail:

It almost makes me feel sad that my company isn’t focusing on the retail sector :).

I’m looking forward to tomorrow, especially to mfp‘s talk about MorphX and TFS.
See you then (or there)!

Data migration: Importing the InventItemGroupForm Table

Klaas Deforche — Tue, 08 Nov 2011 10:23:53 +0000

Hi everyone :-).

I am tasked with doing data migration for a project that is about to go live. One of the things that have to be converted are item groups (InventItemGroup) and their linked dimensions (InventItemGroupForm).

Importing the InventItemGroup table is easy, but InventItemGroupForm is a little bit trickier.
There is a job below that shows how to fill in the LedgerDimension field on the InventItemGroupForm table. I’m not saying I completely understand the new dimension framework, but this method worked for me, and I hope it helps you when you have to do the same thing.

You will notice that you won’t be able to import the InventItemGroupForm table with the excel add-on. You’ll have to use a custom job (or make you own import framework like I did).

This white paper can help too: Implementing the Account and Financial Dimensions Framework (White paper)

static void klforDimensionTest(Args _args)
{
/* input */

// the InventItemGroup record we want to set accounts for
InventItemGroup inventItemGroup = InventItemGroup::find("Car Audio");
// the main account we want to link to our InventItemGroup
MainAccountNum mainAccountNum = "0107";
// The account type we are setting
InventAccountType inventAccountType = InventAccountType::InventIssue;
// the dimension group of the account type
ItemGroupLedgerDimensionGroup itemGroupLedgerDimensionGroup = ItemGroupLedgerDimensionGroup::Inventory;

/* declarations */
Ledger ledger;
MainAccount mainAccount;
DimensionAttributeValueCombination dimensionAttributeValueCombination;
DimensionAttributeValue dimAttributeValue;
DimensionAttribute dimAttribute;
DimensionStorage dimStorage;
RecId hierarchyRecId;

DimensionStorageSegment dimensionStorageSegment;
InventItemGroupForm inventItemGroupForm;
;

if(inventItemGroup.RecId == 0)
{
throw error("InventItemGroup not found");
}

// check if inventItemGroupForm record exists
select firstOnly forUpdate inventItemGroupForm
where inventItemGroupForm.ItemGroupId == inventItemGroup.ItemGroupId
&& inventItemGroupForm.InventAccountType == inventAccountType
&& inventItemGroupForm.LedgerDimensionGroup == itemGroupLedgerDimensionGroup;

if(!inventItemGroupForm)
{
// record does not exists, initialize it
inventItemGroupForm.clear();
inventItemGroupForm.initValue();
inventItemGroupForm.ItemGroupId = inventItemGroup.ItemGroupId;
inventItemGroupForm.InventAccountType = inventAccountType;
inventItemGroupForm.LedgerDimensionGroup = itemGroupLedgerDimensionGroup;
}

// get the ledger record for the current company
ledger = Ledger::findByLegalEntity(CompanyInfo::current());

// lookup main account record
mainAccount = MainAccount::findByMainAccountId(mainAccountNum, false, ledger.ChartOfAccounts);

if (mainAccount.RecId == 0)
{
throw error("MainAccount not found");
}

// check if DAVC exists
select firstOnly dimensionAttributeValueCombination
where dimensionAttributeValueCombination.MainAccount == mainAccount.RecId
&& dimensionAttributeValueCombination.AccountStructure == 0
&& dimensionAttributeValueCombination.LedgerDimensionType == LedgerDimensionType::DefaultAccount;

// when the DAVC does not exist, create it
if(dimensionAttributeValueCombination.RecId == 0)
{
// Cache the dimension attribute that represents the Main account
select firstonly * from dimAttribute where
dimAttribute.RecId == DimensionAttribute::getMainAccountDimensionAttribute();

// Lookup the DAV backing the main account instance
dimAttributeValue = DimensionAttributeValue::findByDimensionAttributeAndEntityInst(dimAttribute.RecId, mainAccount.RecId, false, true);

// lookup the hierarchy for the default acount
hierarchyRecId = DimensionHierarchy::getHierarchyIdByHierarchyType(DimensionHierarchyType::DefaultAccount);

// create new storage
dimStorage = DimensionStorage::construct();
// add the default account structure hierarchy
dimStorage.addAccountStructure(hierarchyRecId);

// create storage segment for the value
dimensionStorageSegment = DimensionStorageSegment::construct(mainAccountNum, dimAttributeValue.RecId, dimAttributeValue.HashKey);
// add the segment to the storage
dimStorage.setSegment(1, dimensionStorageSegment);

// save storage as default account and get the record
dimensionAttributeValueCombination = DimensionAttributeValueCombination::find(dimStorage.saveAsDefaultAccount());
}

// set the ledgerdimension reference field
inventItemGroupForm.LedgerDimension = dimensionAttributeValueCombination.RecId;
// call modifiedfield voor ledgerdimension field to sync inventPosting
inventItemGroupForm.modifiedField(fieldNum(InventItemGroupForm, LedgerDimension));

ttsBegin;

if(inventItemGroupForm.recid == 0)
{
// insert if this is a new record
inventItemGroupForm.insert();
}
else
{
// update existing record
inventItemGroupForm.update();
}

ttsCommit;

info("Done");
}

Comments with ideas / insights / improvements are welcome as always.

See you at Technical Conference in Nice (Nov 14-16)

Klaas Deforche — Mon, 07 Nov 2011 20:17:46 +0000

Hi everyone,

Together with some colleagues, I will be attending the Technical Conference in Nice next week.
I’m very exited, as this is a first for me (but hopefully not last).

I will bring you the news when I get back.
See you there!

AX2012: SysOperation part 3: SysOperationAutomaticUIBuilder

Klaas Deforche — Wed, 24 Aug 2011 10:00:00 +0000

Hi everyone.

This is the third and final part in my series of posts about SysOperation (at least for now). You can find part 1 here and part 2 here.

I will demonstrate how to override methods on the dialog (in this case modified()), and how to read and set properties of controls.

For the sake of this demo, we will add a checkbox to the dialog that will allow us to set the enabled property of the date control.
It should look like this:

1. Modify the data contract

We will need to modify the data contract so a checkbox is displayed on the dialog that we can use to enable or disable the date control.

Add this variable to the class declaration of the KlForCustTesterDataContract class:

NoYesId allowModifyDate;

Then add this method to that same data contract

[DataMemberAttribute,
SysOperationLabelAttribute("Enable date control")]
public NoYesId parmAllowModifyDate(NoYesId _allowModifyDate = allowModifyDate)
{
allowModifyDate = _allowModifyDate;
return allowModifyDate;
}

There’s nothing new here, we already did all of this in part 1

2. Extending SysOperationAutomaticUIBuilder

We will extend the SysOperationAutomaticUIBuilder class so we can override methods and properties of controls on our dialog.

First, create a new class, KlForCustTesterUIBuilder:

class KlForCustTesterUIBuilder extends SysOperationAutomaticUIBuilder
{
}

Things we will need in this class are:

a variable for the date control
a variable for the new checkbox control
our data contract

So we add these variables to the class declaration:

class KlForCustTesterUIBuilder extends SysOperationAutomaticUIBuilder
{
DialogField dialogFieldAllowModifyDate;
DialogField dialogFieldTransDate;

KlForCustTesterDataContract klForCustTesterDataContract;
}

2.1 Adding the override method

We will first write the method that will override the modified of the checkbox control. Simply add a new method to the KlForCustTesterUIBuilder class:

public boolean allowModifyDateModified(FormCheckBoxControl _checkBoxControl)
{
;
// set enabled or disabled based on checkbox
dialogFieldTransDate.enabled(any2enum(dialogFieldAllowModifyDate.value()));
// or alternatively
// dialogFieldTransDate.enabled(_checkBoxControl.checked());

return true;
}

The code above sets the enabled method on the dialogFieldTransDate object based on the value property of dialogFieldAllowModifyDate object, or alternatively, the _checkBoxControl variable.
As you may remember, we declared the DialogField variables in the class declaration. Of course we will still have to initialize these variables , and that’s what we’ll do when overriding the postBuild method.

2.2 Overwriting the postBuild method

Next, we need to override the postBuild method on our KlForCustTesterUIBuilder class. This method will be called after the dialog is created, so it is a good place to put our logic.

Override the method:

public void postBuild()
{
;
super();
}

Next, let’s add some code to this method, starting with the code that retrieves the data contract object, which is pretty easy:

public void postBuild()
{
;
super();

// get datacontract
klForCustTesterDataContract = this.dataContractObject();
}

Next, we retrieve the DialogField objects:

In the code above, the bindInfo() method returns an object of type SysOperationUIBindInfo. This contains information about which dialog controls the data members are bound to. By providing a reference to the parmTransDate and parmAllowModifyDate member when calling the getDialogField() method, we get the dialog control that is associated with each member.

Next, we will register the method we want to override:

public void postBuild()
{
;
super();

// get datacontract
klForCustTesterDataContract = this.dataContractObject();

// get dialog fields
dialogFieldTransDate = this.bindInfo().getDialogField(KlForCustTesterDataContract, methodstr(KlForCustTesterDataContract, parmTransDate));
dialogFieldAllowModifyDate = this.bindInfo().getDialogField(KlForCustTesterDataContract, methodstr(KlForCustTesterDataContract, parmAllowModifyDate));

// register override methods
dialogFieldAllowModifyDate.registerOverrideMethod(methodstr(FormCheckBoxControl, modified), methodstr(KlForCustTesterUIBuilder, allowModifyDateModified), this);
}

As you can see, we can use the registerOverrideMethod() method to override methods on dialog. This is a huge improvement over overriding methods on dialogs in 2009. We simply point to the method we want to override (FormCheckBoxControl.modified) and the method the needs to be executed (KlForCustTesterUIBuilder.allowModifyDateModified).

Finally, we initialize the value of the enabled property, and the complete method will look like this:

3. One more attribute

Now, we’ve created the UIBuilder class, but we still have to link it to our data contract. That’s what the SysOperationContractProcessingAttribute attribute is for.

To link the UIBuilder class to the data contract, open the classDeclaration method of the KlForCustTesterDataContract class, and add the SysOperationContractProcessingAttribute:

[DataContractAttribute,
SysOperationContractProcessingAttribute(classstr(KlForCustTesterUIBuilder))]
class KlForCustTesterDataContract
{
Name name;
TransDate transDate;
str packedQuery;

NoYesId allowModifyDate;
}

4. Testing!

But wait (you already know what I’m going to say right), first click the Generate Incremental CIL button to generate CIL.

Right click the KlForCustTesterServiceController menu item we created on day 2, and choose open. You should see this dialog:

When you check the checkbox, you should see that the date field is enabled.

Download the XPO for part 3 here.

That concludes my blog posts about SysOperation, I hope you like it, and I’m looking forward to your feedback.
Have fun making batches!